BadQuanta
207 lines
7.1 KiB
CMake
207 lines
7.1 KiB
CMake
cmake_minimum_required(VERSION 3.20)
|
|
|
|
project(hdk-sdl
|
|
VERSION 0.0.1
|
|
LANGUAGES CXX
|
|
DESCRIPTION "header only shared_ptr wrappers around SDL3 structs and functions"
|
|
)
|
|
|
|
# Note: The src/ directory contains Doxygen documentation-only .cpp files.
|
|
# This is a header-only library; src/ files are not compiled into any targets.
|
|
|
|
# hdk-sdl OPTIONS
|
|
option(HDK_SDL_TESTS "Build hdk-sdl tests" ${HDK_TESTS})
|
|
option(HDK_SDL_EXAMPLES "Build hdk-sdl examples" ${HDK_EXAMPLES})
|
|
option(HDK_SDL_INSTALL_TARGETS "Enable hdk-sdl install/export stubs" ON)
|
|
option(HDK_SDL_BUNDLE_SDL3 "Build and bundle SDL3 as a static lib with hdk-sdl install" OFF)
|
|
|
|
if(DEFINED HDK_USE_SYSTEM_DEPS)
|
|
set(_hdk_sdl_use_system_default ${HDK_USE_SYSTEM_DEPS})
|
|
else()
|
|
set(_hdk_sdl_use_system_default ON)
|
|
endif()
|
|
|
|
if(DEFINED HDK_CMAKE_POLICY_DIR AND EXISTS "${HDK_CMAKE_POLICY_DIR}/HDKDependencyPolicy.cmake")
|
|
include("${HDK_CMAKE_POLICY_DIR}/HDKDependencyPolicy.cmake")
|
|
elseif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/../cmake/HDKDependencyPolicy.cmake")
|
|
include("${CMAKE_CURRENT_SOURCE_DIR}/../cmake/HDKDependencyPolicy.cmake")
|
|
elseif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/cmake/HDKDependencyPolicy.cmake")
|
|
include("${CMAKE_CURRENT_SOURCE_DIR}/cmake/HDKDependencyPolicy.cmake")
|
|
else()
|
|
message(FATAL_ERROR "Unable to locate HDKDependencyPolicy.cmake")
|
|
endif()
|
|
|
|
option(HDK_SDL_SYSTEM_SDL3 "Prefer system SDL3 before FetchContent fallback" ${_hdk_sdl_use_system_default})
|
|
option(HDK_SDL_FETCH_SDL3_FALLBACK "Fetch SDL3 when a suitable system package is unavailable" ON)
|
|
option(HDK_SDL_SYSTEM_HDK_GRID "Prefer system hdk-grid before FetchContent fallback" ${_hdk_sdl_use_system_default})
|
|
option(HDK_SDL_FETCH_HDK_GRID_FALLBACK "Fetch hdk-grid when a suitable system package is unavailable" ON)
|
|
|
|
if(DEFINED HDK_SDL3_MIN_VERSION)
|
|
set(_hdk_sdl_min_sdl3_version_default "${HDK_SDL3_MIN_VERSION}")
|
|
else()
|
|
set(_hdk_sdl_min_sdl3_version_default "3.4.8")
|
|
endif()
|
|
|
|
if(DEFINED HDK_GRID_MIN_VERSION)
|
|
set(_hdk_sdl_min_grid_version_default "${HDK_GRID_MIN_VERSION}")
|
|
else()
|
|
set(_hdk_sdl_min_grid_version_default "0.0.1")
|
|
endif()
|
|
|
|
if(DEFINED HDK_GRID_GIT_REPOSITORY)
|
|
set(_hdk_sdl_grid_repo_default "${HDK_GRID_GIT_REPOSITORY}")
|
|
else()
|
|
set(_hdk_sdl_grid_repo_default "https://git.ufp.institute/ufp/hdk-grid.git")
|
|
endif()
|
|
|
|
set(HDK_SDL_MIN_SDL3_VERSION "${_hdk_sdl_min_sdl3_version_default}" CACHE STRING "Minimum SDL3 version for system package resolution")
|
|
set(HDK_SDL_MIN_HDK_GRID_VERSION "${_hdk_sdl_min_grid_version_default}" CACHE STRING "Minimum hdk-grid version for system package resolution")
|
|
set(HDK_SDL_HDK_GRID_GIT_REPOSITORY "${_hdk_sdl_grid_repo_default}" CACHE STRING "Git repository used to fetch hdk-grid when package resolution fails")
|
|
set(HDK_SDL_HDK_GRID_GIT_TAG "v${HDK_SDL_MIN_HDK_GRID_VERSION}" CACHE STRING "Git tag used to fetch hdk-grid fallback")
|
|
|
|
if(HDK_SDL_SYSTEM_SDL3 AND HDK_SDL_BUNDLE_SDL3)
|
|
message(FATAL_ERROR "HDK_SDL_SYSTEM_SDL3 and HDK_SDL_BUNDLE_SDL3 are mutually exclusive")
|
|
endif()
|
|
|
|
if(HDK_SDL_EXAMPLES)
|
|
add_subdirectory(examples)
|
|
endif()
|
|
|
|
hdk_resolve_dependency(
|
|
NAME hdk-grid
|
|
TARGETS hdk::hdk-grid hdk-grid
|
|
PACKAGE_NAMES hdk-grid
|
|
MIN_VERSION ${HDK_SDL_MIN_HDK_GRID_VERSION}
|
|
USE_SYSTEM ${HDK_SDL_SYSTEM_HDK_GRID}
|
|
FETCH_FALLBACK ${HDK_SDL_FETCH_HDK_GRID_FALLBACK}
|
|
GIT_REPOSITORY ${HDK_SDL_HDK_GRID_GIT_REPOSITORY}
|
|
GIT_TAG ${HDK_SDL_HDK_GRID_GIT_TAG}
|
|
FETCHCONTENT_NAME hdk-grid
|
|
)
|
|
|
|
if(TARGET hdk-grid AND NOT TARGET hdk::hdk-grid)
|
|
add_library(hdk::hdk-grid ALIAS hdk-grid)
|
|
endif()
|
|
|
|
# FOR SDL Building
|
|
set(_hdk_sdl_need_fetch_sdl3 ON)
|
|
if(TARGET SDL3::SDL3)
|
|
set(_hdk_sdl_need_fetch_sdl3 OFF)
|
|
elseif(HDK_SDL_SYSTEM_SDL3)
|
|
find_package(SDL3 ${HDK_SDL_MIN_SDL3_VERSION} QUIET CONFIG)
|
|
if(SDL3_FOUND)
|
|
set(_hdk_sdl_need_fetch_sdl3 OFF)
|
|
elseif(NOT HDK_SDL_FETCH_SDL3_FALLBACK)
|
|
message(FATAL_ERROR "SDL3 >= ${HDK_SDL_MIN_SDL3_VERSION} not found and HDK_SDL_FETCH_SDL3_FALLBACK=OFF")
|
|
endif()
|
|
endif()
|
|
|
|
if(_hdk_sdl_need_fetch_sdl3)
|
|
set(SDL_TEST OFF CACHE BOOL "Disable SDL tests" FORCE)
|
|
set(SDL_EXAMPLES OFF CACHE BOOL "Disable SDL examples" FORCE)
|
|
set(SDL_INSTALL OFF CACHE BOOL "Disable SDL install" FORCE)
|
|
# NOTE: Possibly disable SDL_PIPEWIRE and/or SDL_PIPEWIRE_SHARED?
|
|
|
|
if(HDK_SDL_BUNDLE_SDL3)
|
|
set(SDL_STATIC ON CACHE BOOL "Build SDL3 as static library for bundling" FORCE)
|
|
set(SDL_SHARED OFF CACHE BOOL "Disable SDL3 shared library for bundling" FORCE)
|
|
endif()
|
|
|
|
include(FetchContent)
|
|
FetchContent_Declare(
|
|
SDL3
|
|
GIT_REPOSITORY https://github.com/libsdl-org/SDL.git
|
|
GIT_TAG release-${HDK_SDL_MIN_SDL3_VERSION}
|
|
)
|
|
FetchContent_MakeAvailable(SDL3)
|
|
endif()
|
|
|
|
include(GNUInstallDirs)
|
|
|
|
add_library(hdk-sdl INTERFACE)
|
|
target_link_libraries(hdk-sdl INTERFACE
|
|
$<BUILD_INTERFACE:SDL3::SDL3>
|
|
$<BUILD_INTERFACE:hdk::hdk-grid>
|
|
$<INSTALL_INTERFACE:SDL3::SDL3>
|
|
$<INSTALL_INTERFACE:hdk::hdk-grid>
|
|
)
|
|
target_include_directories(hdk-sdl INTERFACE
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
|
|
$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
|
|
)
|
|
target_compile_features(hdk-sdl INTERFACE cxx_std_17)
|
|
|
|
if(HDK_SDL_INSTALL_TARGETS)
|
|
include(CMakePackageConfigHelpers)
|
|
|
|
install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/
|
|
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
COMPONENT hdk-sdl_dev
|
|
)
|
|
|
|
# Choose config file based on bundle mode
|
|
if(HDK_SDL_BUNDLE_SDL3)
|
|
set(_hdk_sdl_config_file hdk-sdlConfig-bundled.cmake.in)
|
|
else()
|
|
set(_hdk_sdl_config_file hdk-sdlConfig.cmake.in)
|
|
endif()
|
|
|
|
configure_package_config_file(
|
|
${CMAKE_CURRENT_SOURCE_DIR}/cmake/${_hdk_sdl_config_file}
|
|
${CMAKE_CURRENT_BINARY_DIR}/hdk-sdlConfig.cmake
|
|
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hdk-sdl
|
|
PATH_VARS CMAKE_INSTALL_INCLUDEDIR CMAKE_INSTALL_LIBDIR
|
|
)
|
|
|
|
write_basic_package_version_file(
|
|
${CMAKE_CURRENT_BINARY_DIR}/hdk-sdlConfigVersion.cmake
|
|
VERSION ${PROJECT_VERSION}
|
|
COMPATIBILITY SameMajorVersion
|
|
)
|
|
|
|
install(FILES
|
|
${CMAKE_CURRENT_BINARY_DIR}/hdk-sdlConfig.cmake
|
|
${CMAKE_CURRENT_BINARY_DIR}/hdk-sdlConfigVersion.cmake
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hdk-sdl
|
|
COMPONENT hdk-sdl_dev
|
|
)
|
|
|
|
# Bundled SDL3 install rules
|
|
if(HDK_SDL_BUNDLE_SDL3)
|
|
install(FILES $<TARGET_FILE:SDL3-static>
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hdk-sdl/sdl3-static
|
|
COMPONENT hdk-sdl_dev
|
|
)
|
|
|
|
install(DIRECTORY ${SDL3_SOURCE_DIR}/include/
|
|
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
COMPONENT hdk-sdl_dev
|
|
)
|
|
|
|
configure_file(
|
|
${CMAKE_CURRENT_SOURCE_DIR}/cmake/hdk-sdlBundledSDL3Targets.cmake.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/hdk-sdlBundledSDL3Targets.cmake
|
|
@ONLY
|
|
)
|
|
|
|
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/hdk-sdlBundledSDL3Targets.cmake
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/hdk-sdl
|
|
COMPONENT hdk-sdl_dev
|
|
)
|
|
endif()
|
|
endif()
|
|
|
|
if(HDK_SDL_TESTS)
|
|
add_subdirectory(test)
|
|
endif()
|
|
|
|
|
|
# Documentation Policy
|
|
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/HDKDocumentationPolicy.cmake)
|
|
|
|
# Set package dependencies for building debian packages correctly
|
|
set(hdk-sdl_DEBIAN_DEPENDS "hdk-grid-dev (>= ${HDK_SDL_MIN_HDK_GRID_VERSION}), libsdl3-dev")
|
|
|
|
# CPack Packaging Policy
|
|
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/HDKPackaging.cmake)
|